20. Excel Comment comparer deux colonnes ? Comment compléter une feuille à partir d’une autre ?

---

Comparaison de deux colonnes

Soit la feuille de calcul suivante comportant une liste de fonctionnaires :

Nous voulons remplir la colonne E « Responsable » avec la mention « Oui » pour les responsables de l’organisation. La liste des responsables est inscrite en une autre feuille « Feuil2 » :

Je suppose que les deux feuilles appartiennent au même classeur, et que la colonne A "Prénom Nom" ne comporte pas de doublons.

La formule à écrire en cellule E2 et à copier sur la colonne E par copie incrémentée :

=SI(NB.SI(Feuil2!$A$2:$A$179;A2)>0;"Oui";"")

Compléter une feuille à partir d’une autre

Utilisation de la fonction RECHERCHEV

A l’exemple précédent, nous avons ajouté la mention « Oui » pour les responsables de l’organisation. Nous voulons maintenant ajouter le poste de responsabilité pour chaque responsable en l’extrayant de la colonne B de la feuille « Feuil2 ».

Pour cela nous utiliserons la formule :

=RECHERCHEV(A2;Feuil2!$A$1:$B$179;2;FAUX)

Mais comme nous pouvons le voir à l’extrait suivant, le résultat n’est pas satisfaisant :

En effet, la fonction RECHERCHEV retourne l’erreur #N/A quand la valeur recherchée n’est pas trouvée.

La solution est d’utiliser la fonction SIERREUR. Cette fonction retourne la valeur de son 1^er argument si elle n’est pas une erreur. Sinon, la fonction retourne la valeur de son 2^ème argument. Donc, pour le cas présent, je donne en 2^ème argument la chaine vide "".

La formule en F2 à copier à la colonne F par copie incrémentée est :

=SIERREUR(RECHERCHEV(A2;Feuil2!$A$1:$B$179;2;FAUX);"")

Le résultat :

Utilisation des fonctions EQUIV et INDEX

Le même problème peut être résolu à l’aide de la formule :

=INDEX(Feuil2!$A$2:$B$179;EQUIV(A2;Feuil2!$A$2:$A$179;0);2)

La fonction EQUIV en cette formule retourne la position de la valeur en A2 dans la plage A2:A179 de la feuille « Feuil2 ».

INDEX retourne la valeur dans la plage A2:B179 de la feuille « Feuil2 » à l’intersection de

• la ligne dont le numéro est la valeur retournée par EQUIV et
• la colonne 2.

Mais, encore une fois, la fonction EQUIV retourne l’erreur #N/A quand la valeur recherchée n’est pas trouvée.

Pour ne pas avoir affichée cette erreur, utilisez de préférence la formule :

=SIERREUR(INDEX(Feuil14!$A$2:$B$179;EQUIV(A2;Feuil14!$A$2:$A$179;0);2);"")

---

---