11. Exercice 1 - Fonctions logiques

---

Prérequis

Il convient de lire le cours Fonctions Excel jusqu'au chapitre Fonctions logiques avant d'entamer cet exercice.

Question

Soit l’extrait de feuille de calcul. En colonne B est enregistrée la date de début d'un certain processus. En colonne C, est enregistrée la date d'achèvement de la 1^ère opération et en colonne D la date d'achèvement de la 2^ème opération du processus. Je suppose que chacune des 2 opérations doit durer moins de 20 jours.

Ecrivez les formules appropriées en colonnes E et F permettant de générer les scores de la manière suivante :

1. En E, le score est Mauvais si les 2 opérations ont duré plus de 20 jours. Sinon, le score est Bon.
2. En F, le score est Mauvais si les 2 opérations ont duré plus de 20 jours. Le score est Moyen si l'une des deux opérations a duré plus de 20 jours. Sinon, le score est Bon.

---

Indications Exercice 1 – Fonctions logiques

---

1 - En E, le score est Mauvais si les 2 opérations ont duré plus de 20 jours. Sinon, le score est Bon.

Solution :

Formule en E2 :

=SI(ET(JOURS(C2;B2)>20; JOURS(D2;C2)>20); "Mauvais"; "Bon")

Ou bien :

=SI(ET(C2-B2>20;D2-C2>20); "Mauvais"; "Bon")

Explications :

La fonction JOURS est utilisée pour avoir le nombre de jours entre 2 dates. Mais, nous pouvons utiliser également la différence entre les dates, puisqu'en Excel, les dates sont des valeurs numériques appelées Numéros de série et la différence entre 2 jours succéssifs est 1. La formule :

JOURS(C2;B2)

est équivalente à :

C2-B2

La fonction ET retourne la valeur logique VRAI, si les 2 conditions données en arguments sont vraies. C'est à dire, lorsque les 2 opérations du processus ont duré plus de 20 jours.

La fonction SI a en 1^er argument le résultat de la fonction ET. Lorsque ce résultat est Vrai, alors la fonction SI retourne le texte "Mauvais". Sinon, la fonction SI retourne le texte "Bon".

2 - En F, le score est Mauvais si les 2 opérations ont duré plus de 20 jours. Le score est Moyen si l'une des deux opérations a duré plus de 20 jours. Sinon, le score est Bon.

Solution :

Formule en F2 :

=SI(OU(JOURS(C2;B2)>20; JOURS(D2;C2)>20); SI(ET(JOURS(C2;B2)>20; JOURS(D2;C2)>20) ;"Mauvais"; "Moyen"); "Bon")

Ou bien :

=SI(OU(C2-B2>20; D2-C2>20); SI(ET(C2-B2>20;D2-C2>20); "Mauvais"; "Moyen"); "Bon")

Explications :

Le 1^er argument de la fonction SI est :

OU(C2-B2>20;D2-C2>20)

• Il sera évalué à la valeur logique FALSE, si aucune des 2 opérations du processus n'a duré plus de 20 jours. Dans ce cas, le résultat global est la valeur en 3^ème argument soit le texte "Bon".
• Il sera évalué à la valeur logique VRAI, si l'une ou les 2 opérations du processus ont duré plus de 20 jours. Dans ce cas, le résultat global est l'évaluation de l'expression en 2^ème argument qui est :

SI(ET(C2-B2>20;D2-C2>20); "Mauvais"; "Moyen")

La valeur de cet expression est :

• "Mauvais" lorsque les 2 opérations du processus ont duré plus de 20 jours
• "Moyen" lorsqu'une seule opération du processus a duré plus de 20 jours

---

---